######################################################################
# Cameron Mura, July 2002
# PyMOL script to make an electron density figure, 
# centered near one of the 14 MPD-binding sites in 
# Mth SmAP1 (the P2(1) xtal structure).
######################################################################
# NOTE: for some reason the contact distances are omitted from 
# the final .png file....
######################################################################

# set background color to white
bg_color white

set mesh_radius = 0.016
set stick_radius = 0.12

set dash_gap = 0.14
set dash_radius = 0.04

# load pdb files:

load mth_p21_ump.pdb, mth

# don't need util.ss because we're zooming in on Mth binding site. 
# no ribbons or other cartoons...
#util.ss pae

hide everything, mth

# load XPLOR-formatted 2Fo-Fc and Fo-Fc map files:
load mth_map2fofc.xplor, 2fofc
load mth_mapfofc.xplor, fofc

# define some atoms sets:

select main = (mth and name c,n,o,ca and !c;U,W,X)
select side = (mth and !n;c,n,o and !c;U,W,X)
select wat = (mth and chain W)
select ump = (mth and chain U)
select mpd = (mth and chain X)
select nonump = (mth and !c;U)

select p_cont = (mth and chain X and resid 1 around 10) 
select m_cont = (mth and chain X and resid 1)	
#show spheres, p_cont

distance m_dist = (m_cont), (p_cont), 3.0
				
color black, m_dist	

# show molecule in stick format & color various objects:

show nb_spheres, wat
show sticks, ump
show sticks, mpd
show sticks, main
show sticks, side
color gray, (ump and elem C)
color yellow, (mpd and elem C)
color salmon, ((main or side) and elem C)

# show e-density maps nearby

isomesh mesh1, 2fofc, 1.2, (m_cont), 8
isomesh mesh2, fofc, 3.2, (m_cont), 8
isomesh mesh3, fofc, -3.2, (m_cont), 8

# color maps

color forest, mesh1
color blue, mesh2
color red, mesh3

# zoom in, turn, and clip

zoom (mpd and resid 1) 

clip slab, 10

set antialias = 1
set gamma = 1.5
set orthoscopic = 1

deselect

### cut below here and paste into script ###
set_view (\
    -0.380872071,    0.649468184,   -0.658123195,\
     0.923996150,    0.293635726,   -0.244966209,\
     0.034151349,   -0.701404452,   -0.711944580,\
    -0.227755636,   -0.819920242,  -31.378206253,\
    66.292495728,    3.055999756,   75.068618774,\
    28.450025558,   37.450000763,    1.000000000 )
### cut above here and paste into script ###

ray 800,600
png mth_mpd_density.png
quit