###################################################################
# Cameron Mura, June 2002
#
# PyMOL script to make a .png figure of the interacting surfaces
# between two heptamers ("pae_hept1.pdb" and "pae_hept2.pdb") in
# the asymmetric unit of the Pyrobaculum aerophilum (Pae) SmAP1 
# 14-mer C2221 crystal structure
###################################################################

# set background color to white

bg_color white

# LOAD PDB FILES and SELECT THE 2 HEPTAMERS. 
# Note: the B-factor fields in the "gpa14mer_buriedsurface.pdb" 
# file were set to either 1.0 (at the interface) or 0.0
# (not at the interface).
 
load gpa14mer_buriedsurface.pdb, 14mer
select hept1 = (14mer and c;A,B,C,D,E,F,G)
select hept2 = (14mer and c;H,I,J,K,L,M,N)

# Use PyMOL's "util.ss" Python module to produce secondary structure 
# assignments for the ribbon diagrams, because they don't already
# exist in the input PDB files.

util.ss hept1
util.ss hept2

# Play around with what is displayed and what is hidden for this figure.
# For example, here we hide everything associated with the 2 heptamers, 
# but show cartoon diagrams for them (using "fancy_helices" to make the  
# helical ribbons have nice, Molscript-like edges and to not smooth the 
# loops...) 

hide everything, 14mer
set cartoon_fancy_helices=1
set cartoon_smooth_loops=0

cartoon auto, hept1 ; cartoon auto, hept2
show cartoon, hept1 ; show cartoon, hept2

# Select atoms comprising the interface from heptamers 1 and 2,
# as well as the cysteines near the interface.

select int1 = (hept1 and b > 0)
select int2 = (hept2 and b > 0)
select cys = (14mer and resn cys)
deselect

# Color the 2 heptamers red and blue, and their respective interface
# atoms in slightly lighter shades...

color blue, hept1
color red, hept2
color slate, int1
color salmon, int2
color orange, (cys and element s)

# show the surface corresponding to the heptamer--heptamer interface
# (with 30% transparency). 

show surface, int1
show surface, int2
show spheres, cys
set transparency=0.3

# Selected a nice orientation/view from manual rotation/translation/scaling
# in the PyMOL window (use 'get_view' command), and pasted output here.

set_view (\
     0.960668504,    0.010079085,   -0.277513504,\
    -0.277446538,   -0.007570154,   -0.960711002,\
    -0.011783979,    0.999920547,   -0.004475835,\
     3.410460711,  -15.812123299, -211.135025024,\
    46.160583496,   33.700485229,   79.371162415,\
    86.613555908,  346.613555908,    1.000000000 )

clip slab, 130

# fiddle around with some of the graphics paramters to 
# make the final output file look nicer...
# for example, anti-aliasing to 'smooth' edges and apply 
# a mild gamma correction

set antialias = 1
set gamma = 1.15
set orthoscopic = 1

# Do ray-tracing and write out final .png files.

ray 800,600
png PaeSmAP1_14mer_interface.png

quit

# Here is a view that is orthogonal to the previous one-- i.e., 
# down the 7-fold axis. It's not such an informative view, as 
# far as the interface is concerned).
#### cut below here and paste into script ###
#set_view (\
#     0.999999702,    0.000514440,   -0.000044563,\
#    -0.000514475,    0.999999821,   -0.000012744,\
#     0.000044557,    0.000012748,    1.000000000,\
#     0.000000000,    0.000000000, -207.135025024,\
#    46.160583496,   33.700485229,   79.371162415,\
#    82.613555908,  342.613555908,    1.000000000 )
#### cut above here and paste into script ###