# Cameron Mura; 25-Aug-2006
# Testing 'scene' stuff for John Hart.

load 1AZV.pdb, sod
select water, (resn HOH)
select cu, (resn CU)
select zn, (resn ZN)
deselect

# Scene 1:
show lines, all
scene F1, store, "This is the chingi as loaded:"

# Scene 2:
hide everything, (water | cu | zn)
show lines, all
scene F2, store, "Cleaner image, dehydrated and de-metallated:"

# Scene 3:
hide everything, all
show cartoon, sod
color salmon, chain A
color slate, chain B
set cartoon_smooth_loops,1
set cartoon_fancy_helices,1
set cartoon_highlight_color,grey40
scene F3, store, "Clean cartoon representations:"

# Scene 4:
hide everything, all
show cartoon, sod
color salmon, chain A
color slate, chain B
set cartoon_smooth_loops,1
set cartoon_fancy_helices,1
set cartoon_highlight_color,grey40
set_view (\
     0.123882622,    0.651281416,   -0.748655319,\
    -0.948421597,    0.299586415,    0.103680685,\
     0.291812778,    0.697198629,    0.654800057,\
    -0.000217214,    0.000218015, -155.891601562,\
    55.551078796,   43.905708313,    0.392144620,\
   108.093154907,  203.697418213,    1.000000000 )
scene F4, store, "Clean view down the dimer 2-fold axis:"

# Scene 5:
hide everything, all
show cartoon, sod
show spheres, (cu | zn)
color tv_orange, (cu)
color greencyan, (zn)
scene F5, store, "Show just Cu and Zn as spheres:"

# Scene 6:
hide everything, all
show cartoon, sod
show spheres, (cu | zn)
show spheres, water
#cmd.alter('water','vdw=vdw*0.5')
alter (water), vdw=0.35
rebuild
scene F6, store, "Also show waters as small spheres:"

# Scene 7:
set transparency, 0.5
flag ignore, (! (sod and c;A)), set
delete indicate
show surface
rebuild
#show surface, (sod and chain A)
scene F7, store, "Add a semi-transparent closed surface to just chain A:"
hide surface